1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
|
// Bubble sort
bsort(ret) >< [] => ret~[];
bsort(ret) >< x:xs => bsort(ret)~cnt, B(cnt, x)~xs;
bsort(ret) >< M(x) => ret~x;
B(ret, int x) >< [] => ret~M([x]);
B(ret, int x) >< M(w) => ret~M(x:w);
B(ret, int x) >< (int y):ys
| x<y => ret~(x:cnt), B(cnt, y)~ys
| _ => ret~(y:cnt), B(cnt, x)~ys;
// creates a random list
make_RandList(ret) >< (int n)
| n>0 => ret~(rd:cnt), make_RandList(cnt)~(n-1)
where rd=rand(10000)
| _ => ret~[];
// validation checks
valid(ret) >< [] => ret~False;
valid(ret) >< x:xs => valid_Cons(ret,x)~xs;
valid_Cons(ret, int x) >< [] => ret~True;
valid_Cons(ret, int x) >< (int y):ys
| x<=y => valid_Cons(ret,y)~ys
| _ => ret~False, Eraser~ys;
// The `Eraser' is a built-in agent defined for any agents as follows:
//Eraser >< Alpha(a1, ..., a5) => Eraser~a1, ..., Eraser~a5;
// Main
const LIST_ELEM=40000;
make_RandList(rndlist)~(LIST_ELEM),
bsort(sorted)~rndlist,
valid(ret)~sorted;
ret;
|
